it-swarm.cn

使用TOpenDialog选择目录

我真的很想知道我可以使用TOpenDialog选择目录的各种方式,无论是下载新组件还是使用Delphi提供的内容,但最好使用Delphi提供的内容。

在此之前,我一直在使用SelectDirectory命令,但是我认为程序用户很难找到指定的目录。

我认为SelectDirectory是“弱”的,因为在搜索所需目录时这可能是一个漫长的过程。例如,您要导航到“应用程序数据”目录。在那里导航需要多长时间或困难?最后,用户甚至可能无法到达他们想要的目录。

我需要这样的东西,用户可以在其中复制目录并将其粘贴到顶部的目录地址栏中。

enter image description here

感谢您的所有答复。

47
ple103

您可以使用 TFileOpenDialog (在Vista +上):

with TFileOpenDialog.Create(nil) do
  try
    Options := [fdoPickFolders];
    if Execute then
      ShowMessage(FileName);
  finally
    Free;
  end;

就个人而言,我总是在Vista +上使用TFileOpenDialog,而在XP上则使用SelectDirectory(很好!)进行回退,如下所示:

if Win32MajorVersion >= 6 then
  with TFileOpenDialog.Create(nil) do
    try
      Title := 'Select Directory';
      Options := [fdoPickFolders, fdoPathMustExist, fdoForceFileSystem]; // YMMV
      OkButtonLabel := 'Select';
      DefaultFolder := FDir;
      FileName := FDir;
      if Execute then
        ShowMessage(FileName);
    finally
      Free;
    end
else
  if SelectDirectory('Select Directory', ExtractFileDrive(FDir), FDir,
             [sdNewUI, sdNewFolder]) then
    ShowMessage(FDir)
64
Andreas Rejbrand

您知道两个重载的函数称为FileCtrl.SelectDirectory会产生完全不同的对话框,对吗?

SelectDirectory(s, [], 0);

Screenshot

SelectDirectory('Select a directory', s, s, []);

Screenshot

56
Andreas Rejbrand

只包括

_FileCtrl.pas

var
  sDir:String;
begin
  SelectDirectory('Your caption','',sDir);
end;
_

如果要查看包括桌面在内的所有目录,只需将第二个参数留空。如果将第二个参数设置为任何有效的路径,则对话框将具有该路径到顶层文件夹,并且您将无法浏览该路径。

例如:

SelectDirectory('Your caption','C:\',sDir)不允许您选择_C:\_以外的任何内容,例如_D:\_或_E:\_等。

因此,最好将其保留为空。

6
Shadab Mozaffar

刚刚发现下面的代码在XP和Vista,Win7中)似乎可以正常工作。它为用户提供了一个用于选择目录的UI。它使用TOpenDialog,但向它发送了一些要清除的消息为了选择目录而外观。

在遭受Windows本身提供的有限功能的困扰之后,很高兴能够为我的用户提供一个熟悉的UI,使他们可以舒适地浏览并选择文件夹

我一直在寻找这样的东西很长时间,以为我会在这里发布它,以便其他人可以从中受益。

这是Win 7中的样子:

screen capture

//***********************
//** Choose a directory **
//**   uses Messages   **
//***********************
  //General usage here:
  //  http://www.delphipages.com/forum/showthread.php?p=185734
  //Need a class to hold a procedure to be called by Dialog.OnShow:
  type TOpenDir = class(TObject)
  public
    Dialog: TOpenDialog;
    procedure HideControls(Sender: TObject);
  end;
  //This procedure hides de combo box of file types...
  procedure TOpenDir.HideControls(Sender: TObject);
  const
    //CDM_HIDECONTROL and CDM_SETCONTROLTEXT values from:
    //  doc.ddart.net/msdn/header/include/commdlg.h.html
    //  CMD_HIDECONTROL = CMD_FIRST + 5 = (WM_USER + 100) + 5;
    //Usage of CDM_HIDECONTROL and CDM_SETCONTROLTEXT here:
    //  msdn.Microsoft.com/en-us/library/ms646853%28VS.85%29.aspx
    //  msdn.Microsoft.com/en-us/library/ms646855%28VS.85%29.aspx
    CDM_HIDECONTROL =    WM_USER + 100 + 5;
    CDM_SETCONTROLTEXT = WM_USER + 100 + 4;
    //Component IDs from:
    //  msdn.Microsoft.com/en-us/library/ms646960%28VS.85%29.aspx#_win32_Open_and_Save_As_Dialog_Box_Customization
    //Translation into exadecimal in dlgs.h:
    //  www.koders.com/c/fidCD2C946367FEE401460B8A91A3DB62F7D9CE3244.aspx
    //
    //File type filter...
    cmb1: integer  = $470; //Combo box with list of file type filters
    stc2: integer  = $441; //Label of the file type
    //File name const...
    cmb13: integer = $47c; //Combo box with name of the current file
    edt1: integer  = $480; //Edit with the name of the current file
    stc3: integer  = $442; //Label of the file name combo
  var H: THandle;
  begin
    H:= GetParent(Dialog.Handle);
    //Hide file types combo...
    SendMessage(H, CDM_HIDECONTROL, cmb1,  0);
    SendMessage(H, CDM_HIDECONTROL, stc2,  0);
    //Hide file name label, edit and combo...
    SendMessage(H, CDM_HIDECONTROL, cmb13, 0);
    SendMessage(H, CDM_HIDECONTROL, edt1,  0);
    SendMessage(H, CDM_HIDECONTROL, stc3,  0);
    //NOTE: How to change label text (the lentgh is not auto):
    //SendMessage(H, CDM_SETCONTROLTEXT, stc3, DWORD(pChar('Hello!')));
  end;
//Call it when you need the user to chose a folder for you...
function GimmeDir(var Dir: string): boolean;
var
  OpenDialog: TOpenDialog;
  OpenDir: TOpenDir;
begin
  //The standard dialog...
  OpenDialog:= TOpenDialog.Create(nil);
  //Objetc that holds the OnShow code to hide controls
  OpenDir:= TOpenDir.create;
  try
    //Conect both components...
    OpenDir.Dialog:= OpenDialog;
    OpenDialog.OnShow:= OpenDir.HideControls;
    //Configure it so only folders are shown (and file without extension!)...
    OpenDialog.FileName:= '*.';
    OpenDialog.Filter:=   '*.';
    OpenDialog.Title:=    'Chose a folder';
    //No need to check file existis!
    OpenDialog.Options:= OpenDialog.Options + [ofNoValidate];
    //Initial folder...
    OpenDialog.InitialDir:= Dir;
    //Ask user...
    if OpenDialog.Execute then begin
      Dir:= ExtractFilePath(OpenDialog.FileName);
      result:= true;
    end else begin
      result:= false;
    end;
  finally
    //Clean up...
    OpenDir.Free;
    OpenDialog.Free;
  end;
end;
6
RobertFrank

如果使用 [〜#〜] jvcl [〜#〜] ,则可以使用TJvSelectDirectory。这样,您可以通过设置属性在新旧样式之间切换。例如:

Dlg := TJvSelectDirectory.Create(Self);
try
    Dlg.Title := MyTitle;
    Dlg.InitialDir := MyStartDir;
    Dlg.Options := Dlg.Options + [sdAllowCreate, sdPerformCreate];     
    Dlg.ClassicDialog := False;   //switch style
    if Dlg.Execute() then
      NewDir := Dlg.Directory;
finally
    Dlg.Free;
end; 
3
yonojoy